;;====================================================
;;Display dialog box and prompt user to Delete Voucher
;;====================================================
[Report: Rpt Confirmation]
  Add: Form: frm Confirmation
  Variable: lConfirmation
  Set: lConfirmation: Yes
  Title: "Confirm"
	
[Form: frm Confirmation]
  Add: Part: Prt Heading,Prt Title, Prt YesNo
  Add: Bottom Part: Prt Caption
  Full Width  : No
  No Confirm  : Yes
  Space Left  : 5
  Space Right : 5
  Space Top   : 2
  Space Bottom: 1
  Width: 50% screen
  Height: 50% screen

[Part: Prt Heading]
  Horizontal Align: Centre
  Lines : ln Heading

[Part: Prt Title]
  Horizontal Align: Centre
  Lines : Form SubTitle
  Local : Field : Form SubTitle : Info : $$LocaleString:"Delete Voucher [Yes/No]"

[Part: Prt YesNo]
  Horizontal Align: Centre
  Lines : ln Confirmation

[Part: Prt Caption] 
  Horizontal Align: Centre
  Lines : ln Caption1

[Line: ln Heading]
  Add: Field : fldHeading 

[Line: ln Confirmation]
  Add: Field: fldConfirmation,fldRecyclebinFlag,fldOptionalFlag

[Line: ln Caption1]
  Add: Field: fldCaption1

[Field: fldConfirmation]
  Use: Logical Field
  Set as: ##lConfirmation          
  Modifies: lConfirmation

[Field: fldRecycleBinFlag]
  Use: Logical Field
  Set as: #fldConfirmation
  Set Always: Yes
  Modifies: RecycleBinFlag
  Skip: Yes
  Invisible: Yes

[Field: fldOptionalFlag]
  Use: Logical Field
  Set as: #fldConfirmation
  Set Always: Yes
  Modifies: OptionalFlag
  Skip: Yes
  Invisible: Yes

[Field: fldHeading]
  Info: "Recycle-bin for Tally"

[Field: fldCaption1]
  Info: "Visit:  http://www.rtslink.com"
